;;drawing line from 2 cordinates
.proc line_down_inv
    ;;#  (X_pos, Y_pos)                                     #
    ;;#                     *                               #
    ;;#                         *                           #
    ;;#                             *                       #
    ;;#                                (X_end, Y_end)       #
    ;;NOTE THAT X_pos <= X_end, Y_pos <= Y_end. Min 45deg!
    .include "line.inc"; Defines memory positions, ex X_pos

    ;;We need to clear this memory
    LDA #$00
    STA <V
    STA <dx_2
    STA $FD ; for pixel_draw

    ;; V = 2*(dy -dx)
    ;; where: dy = Y_end - Y_start, dx = X_end - X_start
    LDA X_end
    SEC
    SBC X_pos
    STA >V
    STA >dx_2;  >dx_2 = dx. Needed for dx_2 (not for V)
    LDA Y_end
    SEC
    SBC Y_pos
    STA dy
    SEC
    SBC >V
    STA >V; <V = dy - dx
    mult_16 >V, <V; V = 2*(dy -dx)

    ;dx_2 = dx*2
    mult_16 >dx_2, <dx_2

    ;;D = 2*dy - dx + 2*255
    ;;Our D is bigger then wikipedia because D is unsigned.
    LDA >dx_2
    STA >D
    LDA <dx_2
    STA <D
    Add_16 >D, <D, #$ff, #$01
    Sub_16 >D, <D, dy, #$00

    LDY #$00
    jsr pixel_draw ;;only used first pixel. after this relative position is abused
    CLC ; this makes it that C =0 always on for_x
for_y:
LDX #$00
LDA byte_to_paint
ORA (>btp_mem_pos, X)
STA (>btp_mem_pos, X)
increment_y_pos:
    Add_16 >btp_mem_pos, <btp_mem_pos, #$01, #$00, ! ; I know that C ==0 on for_y
    INY
    CPY #$08 ;
    BEQ move_8px_down
    jmp increment_y_pos_end
move_8px_down:
    ;; +320-8 bytes
    LDY #$00
    Add_16 >btp_mem_pos, <btp_mem_pos,#$38 , #$01
increment_y_pos_end:
    INC Y_pos;; legacy
    LDX Y_pos
    CPX Y_end
    BEQ end

    ;;If D <  %00000010 00000000:  case_2
    ;;else case 1.
    Lag_16 >D, <D, #$00, #$02, case_2
case_1:
    Sub_16 >D, <D, >V, <V; D = D - V
increment_pixel_x:
    CLC
    LDA byte_to_paint
    ROR byte_to_paint
    BCS move_8px_left
    JMP for_y
move_8px_left:
    ;; add +8 to btp_mem_pos. Find more of why in pixel_draw
    Add_16 >btp_mem_pos, <btp_mem_pos, #$08, #$00
    ;; reset byte_to_paint
    LDA #%10000000
    STA byte_to_paint
    JMP for_y
case_2:  ;; C =0 because LAG_16 so we can use !
    Add_16 >D, <D, >dx_2, <dx_2, ! ;D = D + 2*dx
    JMP for_y
end:
    RTS
.endproc